' MODEL GROWTH for Eviews version 6
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 11

' Before running this program you should have used GL11GROWTH
' to create a workfile and a baseline solution

' This program will generate the chart in figure 11.9D
' discussed in par. 11.8.2

smpl @all

' Store original value of shocked value to baseline
genr lambda20_0 = lambda20
genr lambda30_0 = lambda30
genr lambda40_0 = lambda40

' Increase the desired share of equities in household portfolio
smpl 1960 @last
lambda20 = 0.20
lambda30 = -0.04341-0.05
lambda40 = 0.77132
smpl @all

' Select alternative Scenario 9b

growth_mod.scenario(n, a="_9b") "Scenario 9b"

' Set simulation sample
smpl 1947 @last

' Solve the model for the current sample

growth_mod.solve(i=p)

' Store shocked value to scenario
genr lambda20_9b = lambda20
genr lambda30_9b = lambda30
genr lambda40_9b = lambda40
' and get back shocked variable to its baseline value
lambda20 = lambda20_0
lambda30 = lambda30_0
lambda40 = lambda40_0

' Creates charts from simulated variables

' Creates the chart in Figure 11.9D
smpl 1955 2020
graph fig11_9d.line r_l_9b r_m_9b r_b_9b
fig11_9d.options linepat
fig11_9d.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig11_9d.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig11_9d.setelem(3) lcolor(green) lwidth(2) lpat(3)
fig11_9d.name(1) Lending rate
fig11_9d.name(2) Deposit rate
fig11_9d.name(3) Bill rate
fig11_9d.addtext(t,just(c), font("Arial", 12, +b)) Figure 11.9C: Evolution of interest rates\nfollowing a increase in the household desire to hold stock market equities\noffset by a drop in holdings of bills and bonds

show fig11_9d