' MODEL GROWTH for Eviews version 6
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 11

' Before running this program you should have used GL11GROWTH
' to create a workfile and a baseline solution

' This program will generate the charts in figures 11.8A to 11.8E
' discussed in par. 11.8.2

smpl @all

' Store original value of shocked value to baseline
genr eta0_0 = eta0

' Increase the ratio of new loans to personal income
smpl 1960 @last
eta0 = 0.08416
smpl @all

' Select alternative Scenario 8

growth_mod.scenario(n, a="_8") "Scenario 8"

' Set simulation sample
smpl 1947 @last

' Solve the model for the current sample

growth_mod.solve(i=p)

' Store shocked value to scenario
genr eta0_8 = eta0
' and get back shocked variable to its baseline value
eta0 = eta0_0

' Creates charts from simulated variables

' Creates the chart in Figure 11.8A
smpl 1955 2020
graph fig11_8a.line (l_hd_8/yp_8)/(l_hd_0/yp_0) bur_8/bur_0
fig11_8a.options linepat
fig11_8a.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig11_8a.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig11_8a.setelem(2) axis(r)
fig11_8a.name(1) Ratio of personal loans to income
fig11_8a.name(2) Burden of personal debt
fig11_8a.addtext(t,just(c), font("Arial", 12, +b)) Figure 11.8A: Evolution of the loans to income ration and the debt burdern ratio\nfollowing an increase in the gross new loans to personal income ratio

show fig11_8a

' Creates the chart in Figure 11.8B
smpl 1955 2020
graph fig11_8b.line y_k_8/y_k_0 c_k_8/c_k_0
fig11_8b.options linepat
fig11_8b.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig11_8b.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig11_8b.name(1) Real output
fig11_8b.name(2) Real consumption
fig11_8b.addtext(t,just(c), font("Arial", 12, +b)) Figure 11.8B: Evolution of real output and consumption\nfollowing an increase in the gross new loans to personal income ratio

show fig11_8b

' Creates the chart in Figure 11.8C
smpl 1955 2020
graph fig11_8c.line blr_8/blr_0 car_8/car_0
fig11_8c.options linepat
fig11_8c.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig11_8c.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig11_8c.name(1) Bank liquidity ratio
fig11_8c.name(2) Bank capital adequacy ratio
fig11_8c.addtext(t,just(c), font("Arial", 12, +b)) Figure 11.8C: Evolution of banks liquidity and capital adequacy ratios\nfollowing an increase in the gross new loans to personal income ratio

show fig11_8c

' Creates the chart in Figure 11.8D
smpl 1955 2020
graph fig11_8d.line r_l_8
fig11_8d.options linepat
fig11_8d.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig11_8d.name(1) Interest rate on loans
fig11_8d.addtext(t,just(c), font("Arial", 12, +b)) Figure 11.8D: Evolution of the interest rate on loans\nfollowing an increase in the gross new loans to personal income ratio

show fig11_8d

' Creates the chart in Figure 11.8E
smpl 1955 2020
graph fig11_8e.line (gd_8/y_8)/(gd_0/y_0) (psbr_8/y_8)/(psbr_0/y_0)
fig11_8e.options linepat
fig11_8e.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig11_8e.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig11_8e.name(1) Government debt to GDP ratio
fig11_8e.name(2) Government deficit to GDP ratio
fig11_8e.addtext(t,just(c), font("Arial", 12, +b)) Figure 11.8E: Evolution of the debt and deficit to GDP ratios\nfollowing an increase in the gross new loans to personal income ratio

show fig11_8e