' MODEL REG for Eviews version 6
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 6
' This program creates model REG, described in chapter 6, and simulates the model
' to produce results in par. 6.5
' ****************************************************************************
' Copyright (c) 2006 Gennaro Zezza
' Permission is hereby granted, free of charge, to any person obtaining a
' copy of this software and associated documentation files (the "Software"),
' to deal in the Software without restriction, including without limitation
' the rights to use, copy, modify, merge, publish, distribute, sublicense,
' and/or sell copies of the Software, and to permit persons to whom the
' Software is furnished to do so, subject to the following conditions:
'
' The above copyright notice and this permission notice shall be included in
' all copies or substantial portions of the Software.
'
' THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
' IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
' FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
' AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
' LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
' FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
' IN THE SOFTWARE.
' ****************************************************************************
' Create a workfile, naming it REG, to hold annual data from 1945 to 2010
wfcreate(wf=reg, page=annual) a 1945 2010
' Creates and documents series
series b_cb
b_cb.displayname Bills held by the Central bank
series b_h
b_h.displayname Overall bills outstanding
series b_h_n
b_h_n.displayname Bills held by households, Region N
series b_h_s
b_h_s.displayname Bills held by households, Region S
series b_s
b_s.displayname Supply of government bills
series cons_n
cons_n.displayname Households consumption, Region N
series cons_s
cons_s.displayname Households consumption, Region S
series g
g.displayname Overall government expenditure
series g_n
g_n.displayname Government expenditure, Region N
series g_s
g_s.displayname Government expenditure, Region S
series h_h
h_h.displayname Overall cash outstanding
series h_h_n
h_h_n.displayname Cash held by households, Region N
series h_h_s
h_h_s.displayname Cash held by households, Region S
series h_s
h_s.displayname Supply of cash
series im_n
im_n.displayname Imports, Region N
series im_s
im_s.displayname Imports, Region S
series r
r.displayname Interest rate on bills
series r_bar
r_bar.displayname Interest rate on bills set exogenously
series t
t.displayname Overall tax payments
series t_n
t_n.displayname Tax payments, Region N
series t_s
t_s.displayname Tax payments, Region S
series v_n
v_n.displayname Households wealth, Region N
series v_s
v_s.displayname Households wealth, Region S
series x_n
x_n.displayname Exports, Region N
series x_s
x_s.displayname Exports, Region S
series y_n
y_n.displayname National income, Region N
series y_s
y_s.displayname National income, Region S
series yd_n
yd_n.displayname National disposable income, Region N
series yd_s
yd_s.displayname National disposable income, Region S
' Generate parameters
series alpha1_n
alpha1_n.displayname Propensity to consume out of income in Region N
series alpha1_s
alpha1_s.displayname Propensity to consume out of income in Region S
series alpha2_n
alpha2_n.displayname Propensity to consume out of wealth in Region N
series alpha2_s
alpha2_s.displayname Propensity to consume out of wealth in Region S
series lambda0_n
lambda0_n.displayname Parameter in asset demand function, Region N
series lambda0_s
lambda0_s.displayname Parameter in asset demand function, Region S
series lambda1_n
lambda1_n.displayname Parameter in asset demand function, Region N
series lambda1_s
lambda1_s.displayname Parameter in asset demand function, Region S
series lambda2_n
lambda2_n.displayname Parameter in asset demand function, Region N
series lambda2_s
lambda2_s.displayname Parameter in asset demand function, Region S
series mu_n
mu_n.displayname Import propensity, Region N
series mu_s
mu_s.displayname Import propensity, Region S
series theta
theta.displayname Tax rate
' Set sample size to all workfile range
smpl @all
' Assign values for
' PARAMETERS
alpha1_n = 0.6
alpha1_s = 0.7
alpha2_n = 0.4
alpha2_s = 0.3
lambda0_n = 0.635
lambda0_s = 0.67
lambda1_n = 5
lambda1_s = 6
lambda2_n = 0.01
lambda2_s = 0.07
mu_n = 0.18781
mu_s = 0.18781
theta = 0.2
' EXOGENOUS
g_n = 20
g_s = 20
r_bar = 0.025
r = r_bar
' Starting values for stocks
b_cb = 43.244
b_h_n = 64.865
b_h_s = 64.865
b_h = b_h_n + b_h_s
b_s = b_h + b_cb
v_n = 86.487
v_s = 86.487
h_h_n = v_n - b_h_n
h_h_s = v_s - b_h_s
h_h = h_h_n + h_h_s
h_s = h_h
' Create a model object, and name it reg_mod
model reg_mod
' Add equations to model REG
' Determination of national income in Region N - eq. 6.1
reg_mod.append y_n = cons_n + g_n + x_n - im_n
' Determination of national income in Region S - eq. 6.2
reg_mod.append y_s = cons_s + g_s + x_s - im_s
' Imports in Region N - eq. 6.3
reg_mod.append im_n = mu_n*y_n
' Imports in Region S - eq. 6.4
reg_mod.append im_s = mu_s*y_s
' Exports of Region N - eq. 6.5
reg_mod.append x_n = im_s
' Exports of Region S - eq. 6.6
reg_mod.append x_s = im_n
' Disposable income in Region N - eq. 6.7
reg_mod.append yd_n = y_n - t_n + r(-1)*b_h_n(-1)
' Disposable income in Region S - eq. 6.8
reg_mod.append yd_s = y_s - t_s + r(-1)*b_h_s(-1)
' Tax payments in Region N - eq. 6.9
reg_mod.append t_n = theta*(y_n + r(-1)*b_h_n(-1))
' Tax payments in Region S - eq. 6.10
reg_mod.append t_s = theta*(y_s + r(-1)*b_h_s(-1))
' Wealth accumulation in Region N - eq. 6.11
reg_mod.append v_n = v_n(-1) + (yd_n - cons_n)
' Wealth accumulation in Region S - eq. 6.12
reg_mod.append v_s = v_s(-1) + (yd_s - cons_s)
' Consumption function in Region N - eq. 6.13
reg_mod.append cons_n = alpha1_n*yd_n + alpha2_n*v_n(-1)
' Consumption function in Region S - eq. 6.14
reg_mod.append cons_s = alpha1_s*yd_s + alpha2_s*v_s(-1)
' Cash money held in Region N - eq. 6.15
reg_mod.append h_h_n = v_n - b_h_n
' Cash money held in Region S - eq. 6.16
reg_mod.append h_h_s = v_s - b_h_s
' Demand for government bills in Region N - eq. 6.17
reg_mod.append b_h_n = v_n*(lambda0_n + lambda1_n*r - lambda2_n*(yd_n/v_n))
' Demand for government bills in Region S - eq. 6.18
reg_mod.append b_h_s = v_s*(lambda0_s + lambda1_s*r - lambda2_s*(yd_s/v_s))
' Overall tax payments - eq. 6.19
reg_mod.append t = t_n + t_s
' Overall government expenditure - eq. 6.20
reg_mod.append g = g_n + g_s
' Total bills outstanding - eq. 6.21
reg_mod.append b_h = b_h_n + b_h_s
' Total cash outstanding - eq. 6.22
reg_mod.append h_h = h_h_n + h_h_s
' Supply of government bills - eq. 6.23
reg_mod.append b_s = b_s(-1) + (g + r(-1)*b_s(-1)) - (t + r(-1)*b_cb(-1))
' Supply of cash - eq. 6.24
reg_mod.append h_s = h_s(-1) + b_cb - b_cb(-1)
'reg_mod.append h_s = b_cb (Note: specification in WG macro)
' Government bills held by the central bank - eq. 6.25
reg_mod.append b_cb = b_s - b_h
' Interest rate as policy instrument - eq. 6.26
reg_mod.append r = r_bar
' End of model
' Select the baseline scenario
reg_mod.scenario baseline
' Drop first observation to get starting values for solving the model
smpl 1946 @last
' First experiment: increase in the propensity to import of Region S
smpl 1960 @last
mu_s = 0.20781
smpl @all
' Solve the model for the current sample
reg_mod.solve(i=p)
' stores g_s for the current scenario
series g_s_0 = g_s
' Creates charts from simulated variables
' Creates the chart in Figure 6.1
smpl 1950 2000
graph fig6_1.line v_s_0-v_s_0(-1) t_s_0-(g_s_0+r_0*b_h_s_0(-1)) x_s_0-im_s_0
fig6_1.options linepat
fig6_1.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig6_1.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig6_1.setelem(3) lcolor(blue) lwidth(2) lpat(3)
fig6_1.name(1) Change in households wealth - S Region
fig6_1.name(2) Government balance with the S Region
fig6_1.name(3) Trade balance - S Region
fig6_1.addtext(t,just(c)) Figure 6.1: Evolution of balances in the S Region with an increase in import propensity
show fig6_1
' Creates the chart in Figure 6.2
graph fig6_2.line y_n_0 y_s_0
fig6_2.options linepat
fig6_2.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig6_2.setelem(2) lcolor(red) lwidth(2) lpat(2)
fig6_2.name(1) North Region GDP
fig6_2.name(2) South Region GDP
fig6_2.addtext(t,just(c)) Figure 6.2 Evolution of GDP in the N and S Region\n following an increase in the import propensity of the S Region
show fig6_2
' Second experiment: increase in government expenditure in Region S
smpl @all
' get the propensity to import back to its stable value
mu_s = 0.18781
' Select the first alternative Scenario
reg_mod.scenario "Scenario 1"
smpl 1960 @last
g_s = 25
smpl @all
' Solve the model for the current sample
reg_mod.solve(i=p)
' stores g_s for the current scenario
series g_s_1 = g_s
smpl 1950 2000
' Creates the chart in Figure 6.3
graph fig6_3.line y_n_1 y_s_1
fig6_3.options linepat
fig6_3.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig6_3.setelem(2) lcolor(red) lwidth(2) lpat(2)
fig6_3.name(1) North Region GDP
fig6_3.name(2) South Region GDP
fig6_3.addtext(t,just(c)) Figure 6.3 Evolution of GDP in the N and S Region\n following an increase in govt. expenditure of the S Region
show fig6_3
' Creates the chart in Figure 6.4
graph fig6_4.line v_s_1-v_s_1(-1) t_s_1-(g_s_1+r_1*b_h_s_1(-1)) x_s_1-im_s_1
fig6_4.options linepat
fig6_4.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig6_4.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig6_4.setelem(3) lcolor(blue) lwidth(2) lpat(3)
fig6_4.name(1) Change in households wealth - S Region
fig6_4.name(2) Government balance with the S Region
fig6_4.name(3) Trade balance - S Region
fig6_4.addtext(t,just(c)) Figure 6.4: Evolution of balances in the S Region\n following an increase in govt. expenditure in the S Region
show fig6_4
' Third experiment: increase in household saving propensity Region S
smpl @all
' get government expenditure in Region S back to its stable value
g_s = 20
' Creates and select the second alternative Scenario
reg_mod.scenario(n) "Scenario 2"
smpl 1960 @last
alpha1_s = 0.6
smpl @all
' Solve the model for the current sample
reg_mod.solve(i=p)
' stores g_s for the current scenario
series g_s_2 = g_s
smpl 1950 2000
' Creates the chart in Figure 6.5
graph fig6_5.line y_n_2 y_s_2
fig6_5.options linepat
fig6_5.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig6_5.setelem(2) lcolor(red) lwidth(2) lpat(2)
fig6_5.name(1) North Region GDP
fig6_5.name(2) South Region GDP
fig6_5.addtext(t,just(c)) Figure 6.5 Evolution of GDP in the N and S Region\n following an increase in the saving propensity of the S Region
show fig6_5
' Creates the chart in Figure 6.6
graph fig6_6.line v_s_2-v_s_2(-1) t_s_2-(g_s_2+r_2*b_h_s_2(-1)) x_s_2-im_s_2
fig6_6.options linepat
fig6_6.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig6_6.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig6_6.setelem(3) lcolor(blue) lwidth(2) lpat(3)
fig6_6.name(1) Change in households wealth - S Region
fig6_6.name(2) Government balance with the S Region
fig6_6.name(3) Trade balance - S Region
fig6_6.addtext(t,just(c)) Figure 6.6: Evolution of balances in the S Region\n following an increase in the saving propensity of the S Region
show fig6_6
' Fourth experiment: increase in the liquidity preference in Region S
smpl @all
' get saving propensity in Region S back to its stable value
alpha1_s = 0.7
' Creates and select the third alternative Scenario
reg_mod.scenario(n) "Scenario 3"
smpl 1960 @last
lambda0_s = 0.75
smpl @all
' Solve the model for the current sample
reg_mod.solve(i=p)
' stores g_s for the current scenario
series g_s_3 = g_s
smpl 1950 2000
' Creates the chart in Figure 6.7
graph fig6_7.line v_s_3-v_s_3(-1) t_s_3-(g_s_3+r_3*b_h_s_3(-1)) x_s_3-im_s_3
fig6_7.options linepat
fig6_7.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig6_7.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig6_7.setelem(3) lcolor(blue) lwidth(2) lpat(3)
fig6_7.name(1) Change in households wealth - S Region
fig6_7.name(2) Government balance with the S Region
fig6_7.name(3) Trade balance - S Region
fig6_7.addtext(t,just(c)) Figure 6.7: Evolution of balances in the S Region\n following an increase in the liquidity preference of the S Region
show fig6_7