' MODEL PC for Eviews version 5.1
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 4

' This program creates model PC, described in chapter 4, and simulates the model
' to produce results in figures 4.3 & 4.4,
' discussed in par. 4.5


' ****************************************************************************
' Copyright (c) 2006 Gennaro Zezza
' Permission is hereby granted, free of charge, to any person obtaining a 
' copy of this software and associated documentation files (the "Software"),
' to deal in the Software without restriction, including without limitation
' the rights to use, copy, modify, merge, publish, distribute, sublicense, 
' and/or sell copies of the Software, and to permit persons to whom the 
' Software is furnished to do so, subject to the following conditions:
' 
' The above copyright notice and this permission notice shall be included in 
' all copies or substantial portions of the Software.
' 
' THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR 
' IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, 
' FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE 
' AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER 
' LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING 
' FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS 
' IN THE SOFTWARE.
' ****************************************************************************

' Create a workfile, naming it PC, to hold annual data from 1945 to 2010

wfcreate(wf=pc, page=annual) a 1945 2010

' Creates and documents series
series b_cb
b_cb.displayname Government bills held by Central Bank
series b_h
b_h.displayname Government bills held by households
series b_s
b_s.displayname Government bills supplied by government
series cons
cons.displayname Consumption goods
series g
g.displayname Government goods
series h_h
h_h.displayname Cash money held by households
series h_s
h_s.displayname Cash money supplied by central bank
series r
r.displayname Interest rate on government bills
series r_bar
r_bar.displayname Interest rate as policy instrument
series t
t.displayname Taxes
series v
v.displayname Households wealth
series y
y.displayname Income = GDP
series yd
yd.displayname Disposable income of households

' Generate parameters
series alpha1
alpha1.displayname Propensity to consume out of income
series alpha2
alpha2.displayname Propensity to consume out of wealth
series lambda0
lambda0.displayname Parameter in asset demand function
series lambda1
lambda1.displayname Parameter in asset demand function
series lambda2
lambda2.displayname Parameter in asset demand function
series theta
theta.displayname Tax rate

' Set sample size to all workfile range
smpl @all

' Assign values for
'   PARAMETERS
alpha1=0.6
alpha2=0.4
lambda0 = 0.635
lambda1 = 5
lambda2 = 0.01
theta=0.2
'   EXOGENOUS
g=20
r_bar = 0.025
r = r_bar
' Shock to the interest rate
smpl 1960 @last
r_bar = 0.035
smpl @all
'   Starting values for stocks
b_cb = 21.576
b_h = 64.865
b_s = b_h+b_cb
h_h = 21.62
h_s = h_h
v = b_h + h_h

' Create a model object, and name it pc_mod

model pc_mod

' Add equations to model PC

' Determination of output - eq. 4.1
pc_mod.append y = cons + g

' Disposable income - eq. 4.2
pc_mod.append yd = y - t + r(-1)*b_h(-1)

' Tax payments - eq. 4.3
pc_mod.append t = theta*(y + r(-1)*b_h(-1))

' Wealth accumulation - eq. 4.4
pc_mod.append v = v(-1) + (yd - cons)

' Consumption function - eq. 4.5
pc_mod.append cons = alpha1*yd + alpha2*v(-1)

' Cash money - eq. 4.6
pc_mod.append h_h = v - b_h

' Demand for government bills - eq. 4.7
pc_mod.append b_h = v*(lambda0 + lambda1*r - lambda2*(yd/v))

' Supply of government bills - eq. 4.8
pc_mod.append b_s = b_s(-1) + (g + r(-1)*b_s(-1)) - (t + r(-1)*b_cb(-1))

' Supply of cash - eq. 4.9
pc_mod.append h_s = h_s(-1) + b_cb - b_cb(-1)

' Government bills held by the central bank - eq. 4.10
pc_mod.append b_cb = b_s - b_h

' Interest rate as policy instrument - eq. 4.11
pc_mod.append r = r_bar

' End of model

' Select the baseline scenario

pc_mod.scenario baseline

' Drop first observation to get starting values for solving the model
smpl 1946 @last

' Solve the model for the current sample

pc_mod.solve

' Creates charts from simulated variables

' Creates the chart in Figure 4.3
smpl 1950 2000
graph fig4_3.line h_h_0/v_0 b_h_0/v_0
fig4_3.options linepat
fig4_3.setelem(2) axis(right)
fig4_3.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig4_3.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig4_3.name(1) Share of money balances in households portfolio
fig4_3.name(2) Share of bills in households portfolio
fig4_3.addtext(t) Figure 4.3: Shares of Bh and Hh in wealth, following an increase in r
fig4_3.scale(left) linear range(0.19, 0.26) overlap
fig4_3.scale(right) linear range(0.74, 0.81) overlap

show fig4_3

' Creates the chart in Figure 4.4
smpl 1957 2001
graph fig4_4.line yd_0 cons_0
fig4_4.options linepat
fig4_4.setelem(1) lcolor(blue) lwidth(2) lpat(1)
fig4_4.setelem(2) lcolor(red) lwidth(2) lpat(2)
fig4_4.name(1) Disposable income
fig4_4.name(2) Consumption
fig4_4.addtext(t) Figure 4.4: Evolution of Yd and C following an increase in r

show fig4_4