' MODEL SIMEX for Eviews version 5.1
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 3

' This program creates model SIMEX, described in chapter 3, par.7, 
' starting from equilibrium values, and simulates the model
' to produce results in figures 3.6 and 3.7


' ****************************************************************************
' Copyright (c) 2006 Gennaro Zezza
' Permission is hereby granted, free of charge, to any person obtaining a 
' copy of this software and associated documentation files (the "Software"),
' to deal in the Software without restriction, including without limitation
' the rights to use, copy, modify, merge, publish, distribute, sublicense, 
' and/or sell copies of the Software, and to permit persons to whom the 
' Software is furnished to do so, subject to the following conditions:
' 
' The above copyright notice and this permission notice shall be included in 
' all copies or substantial portions of the Software.
' 
' THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR 
' IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, 
' FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE 
' AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER 
' LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING 
' FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS 
' IN THE SOFTWARE.
' ****************************************************************************

' Create a workfile, naming it SIMEXB, to hold annual data from 1945 to 2010

wfcreate(wf=simexb, page=annual) a 1945 2010

' Creates and documents series
series c_d
c_d.displayname Consumption goods demand by households
series c_s
c_s.displayname Consumption goods supply
series g_d
g_d.displayname Government goods, demand
series g_s
g_s.displayname Government goods, supply
series h_d
h_d.displayname Demand for cash money by households
series h_h
h_h.displayname Cash money held by households
series h_s
h_s.displayname Cash money supplied by government
series n_d
n_d.displayname Demand for labour
series n_s
n_s.displayname Supply of labour
series t_d
t_d.displayname Taxes, "demand"
series t_s
t_s.displayname Taxes, "supply"
series w
w.displayname Wage rate
series y
y.displayname Income = GDP
series yd
yd.displayname Disposable income of households
series yde
yde.displayname Expected disposable income of households
series ydstar
yde.displayname Exogenously fixed expected disposable income of households

' Generate parameters
series alpha1
alpha1.displayname Propensity to consume out of income
series alpha2
alpha2.displayname Propensity to consume out of wealth
series theta
theta.displayname Tax rate

' Set sample size to all workfile range
smpl @all

' Assign values for
'   PARAMETERS
alpha1=0.6
alpha2=0.4
theta=0.2
'   EXOGENOUS
' Government expenditure increases by 5 in 1960
smpl @first 1959
g_d=20
smpl 1960 @last
g_d = 25
smpl @all
w=1
ydstar = 80
'   Starting values for stocks
h_h = 80
h_s = 80
h_d = 80
' Starting (equilibrium) values
yd = 80
yde = ydstar
c_d = 80
c_s = c_d
g_s = g_d
y = c_s + g_s
n_d = y/w
n_s = n_d
t_d = theta*w*n_s
t_s = t_d


' Create a model object, and name it simexb_mod

model simexb_mod

' Add equations to model SIMEXB

simexb_mod.append c_s = c_d
simexb_mod.append g_s = g_d
simexb_mod.append t_s = t_d
simexb_mod.append n_s = n_d
simexb_mod.append yd = w*n_s - t_s
simexb_mod.append t_d = theta*w*n_s
simexb_mod.append c_d = alpha1*yde + alpha2*h_h(-1)
simexb_mod.append h_s = h_s(-1) + g_d - t_d
simexb_mod.append h_h = h_h(-1) + yd - c_d
simexb_mod.append h_d = h_s(-1) + yde - c_d
simexb_mod.append y = c_s + g_s
simexb_mod.append n_d = y/w
simexb_mod.append yde = ydstar

' Select the baseline scenario

simexb_mod.scenario baseline

' Drop first observation in order to compute disposable income

smpl 1947 2010

' Solve the model for the current sample

simexb_mod.solve


' Create variables for (simulated) changes in stocks
genr dh_s_0 = h_s_0 - h_s_0(-1)
genr dh_h_0 = h_h_0 - h_h_0(-1)
genr dh_d_0 = h_d_0 - h_d_0(-1)

' Creates charts from simulated variables


' Creates the chart in Figure 3.6
smpl 1957 2001
graph fig3_6.line g_d/theta y_0
fig3_6.options linepat
fig3_6.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig3_6.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig3_6.name(1) Steady state solution for Income Y
fig3_6.name(2) Income Y
fig3_6.addtext(t) Figure 3.6: Impact on Y and Y* of an increase in G when YDe remains fixed
show fig3_6

' Creates the chart in Figure 3.7
smpl 1957 2001
graph fig3_7.line h_h_0 yd_0 c_d_0 yde_0
fig3_7.options linepat
fig3_7.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig3_7.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig3_7.setelem(3) lcolor(blue) lwidth(2) lpat(3)
fig3_7.setelem(4) lcolor(gray) lwidth(2) lpat(4)
fig3_7.name(1) Wealth H
fig3_7.name(2) Disposable Income YD
fig3_7.name(3) Consumption C
fig3_7.name(4) Expected disposable Income YDe
fig3_7.addtext(t) Figure 3.6: Impact on Y and Y* of an increase in G when YDe remains fixed

show fig3_7