' MODEL DIS for Eviews version 4.1
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 9

' This program creates model DIS with exogenous expectations,
' described in appendix 2 to chapter 9, and simulates the model
' to produce figures A9.1 and A9.2

' ****************************************************************************
' Copyright (c) 2006 Gennaro Zezza
' Permission is hereby granted, free of charge, to any person obtaining a 
' copy of this software and associated documentation files (the "Software"),
' to deal in the Software without restriction, including without limitation
' the rights to use, copy, modify, merge, publish, distribute, sublicense, 
' and/or sell copies of the Software, and to permit persons to whom the 
' Software is furnished to do so, subject to the following conditions:
' 
' The above copyright notice and this permission notice shall be included in 
' all copies or substantial portions of the Software.
' 
' THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR 
' IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, 
' FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE 
' AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER 
' LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING 
' FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS 
' IN THE SOFTWARE.
' ****************************************************************************

' Create a workfile, naming it DIS, to hold annual data from 1945 to 2010

create dis a 1945 2010

' Creates and documents series
series add
add.displayname Spread of loans rate over the deposit rate
series c_k
c_k.displayname Real consumption
series cons
cons.displayname Consumption at current prices
series f
f.displayname Realized firms profits
series f_b
f_b.displayname Realized banks profits
series in
in.displayname Stock of inventories at current costs
series in_k
in_k.displayname Real inventories
series in_k_e
in_k_e.displayname Expected real inventories
series in_k_t
in_k_t.displayname Target level of real inventories
series l_d
l_d.displayname Demand for loans
series l_s
l_s.displayname Supply of loans
series m_h
m_h.displayname Deposits held by households
series m_h_k
m_h_k.displayname Real value of deposits held by households
series m_s
m_s.displayname Supply of deposits
series n
n.displayname Employment level
series nhuc
nhuc.displayname Normal historic unit costs
series pr
pr.displayname Labour productivity
series p
p.displayname Price level
series r_l
r_l.displayname Interest rate on loans
series r_l_bar
r_l_bar.displayname Interest rate on loans - set exogenously
series r_m
r_m.displayname Interest rate on deposits
series s
s.displayname Sales at current prices
series s_k
s_k.displayname Real sales
series s_k_e
s_k_e.displayname Expected real sales
series uc
uc.displayname Unit costs
series w
w.displayname Wage rate
series wb
wb.displayname The wage bill
series y_k
y_k.displayname Real output
series yd
yd.displayname Disposable income
series yd_k_hs
yd_k_hs.displayname Haig-Simons measure of real disposable income
series yd_k_hse
yd_k_hse.displayname Expected HS real disposable income

' Generate parameters
series alpha0
alpha0.displayname Autonomous consumption
series alpha1
alpha1.displayname Propensity to consume out of income
series alpha2
alpha2.displayname Propensity to consume out of wealth
series beta
beta.displayname Parameter in expectation formations on real sales
series eps
eps.displayname Parameter in expectation formations on real disposable income
series gamma
gamma.displayname Speed of adjustment of inventories to the target level
series phi
phi.displayname Mark-up on unit costs
series sigmat
sigmat.displayname Target inventories to sales ratio

' Set sample size to all workfile range
smpl @all

' Assign values for
'   PARAMETERS
alpha0 = 15
alpha1 = 0.8
alpha2 = 0.1
beta = 0.75
eps = 0.75
gamma = 0.25
phi = 0.25
sigmat = 0.15
'   EXOGENOUS
add = 0.02
pr = 1
r_l_bar = 0.04
w = 0.86
' Steady state values
uc = w/pr
nhuc = (1+sigmat*r_l_bar)*uc
p = (1+phi)*nhuc
yd_k_hs = alpha0/(1-alpha1-alpha2*sigmat*uc/p)
c_k = yd_k_hs
s_k = c_k
'   STARTING VALUES FOR STOCKS
in_k = sigmat*s_k
in = in_k*uc
l_d = in
m_h = l_d
m_h_k = m_h/p
m_s = m_h
l_s = l_d
' STARTING VALUES FOR ENDOGENOUS
s_k_e = s_k
yd_k_hse = yd_k_hs
r_l = r_l_bar
r_m = r_l - add

' Create a model object, and name it dis_mod

model dis_mod

' Add equations to model DIS

' The production decision

' Real output - eq. 9.1
dis_mod.append y_k = s_k_e + in_k_e - in_k(-1)

' Target level of real inventories - eq. 9.2
dis_mod.append in_k_t = sigmat*s_k_e

' Expected real inventories - eq. 9.3
dis_mod.append in_k_e = in_k(-1) + gamma*(in_k_t - in_k(-1))

' Real inventories - eq. 9.4
dis_mod.append in_k = in_k(-1) + y_k - s_k

' Real sales - eq. 9.6
dis_mod.append s_k = c_k

' Employment - eq. 9.7
dis_mod.append n = y_k/pr

' The wage bill - eq. 9.8
dis_mod.append wb = n*w

' Unit costs - eq. 9.9
dis_mod.append uc = wb/y_k

' Stock of inventories - eq. 9.10
dis_mod.append in = in_k*uc

' The pricing decision

' Sales at current prices - eq. 9.11
dis_mod.append s = p*s_k

' Price level - eq. 9.12
dis_mod.append p = (1 + phi)*nhuc

' Normal historic unit costs - eq. 9.13
dis_mod.append nhuc = (1 - sigmat)*uc + sigmat*(1 + r_l(-1))*uc(-1)

' Firms profits - eq. 9.14
dis_mod.append f = s - wb + in - in(-1) - r_l(-1)*in(-1)

' The banking system

' Demand for loans - eq. 9.15
dis_mod.append l_d = in

' Supply of loans - eq. 9.16
dis_mod.append l_s = l_d

' Supply of deposits - eq. 9.17
dis_mod.append m_s = l_s

' Interest rate on loans - eq. 9.18
dis_mod.append r_l = r_l_bar

' Interest rate on deposits - eq. 9.19
dis_mod.append r_m = r_l - add

' Realized banks profits - eq. 9.20
dis_mod.append f_b = r_l(-1)*l_d(-1) - r_m(-1)*m_h(-1)

' The consumption decision

' Disposable income - eq. 9.21
dis_mod.append yd = wb + f + f_b + r_m(-1)*m_h(-1)

' Holding of banks deposit - eq. 9.22
dis_mod.append m_h = m_h(-1) + yd - cons

' Haig-Simons measure of real disposable income - eq. 9.23
dis_mod.append yd_k_hs = c_k + (m_h_k - m_h_k(-1))

' Consumption at current prices - eq. 9.24
dis_mod.append cons = c_k*p

' Real value of holding of banks deposit - eq. 9.25
dis_mod.append m_h_k = m_h/p

' Consumption decision - eq. 9.26
dis_mod.append c_k = alpha0 + alpha1*yd_k_hse + alpha2*m_h_k(-1)

' Expectation on Real HS disposable income - eq. 9.27
dis_mod.append yd_k_hse = eps*yd_k_hs(-1) + (1 - eps)*yd_k_hse(-1)

' end of model equations

' First experiment: increase in expected real sales
smpl 1960 @last
s_k_e = 85
smpl @all

' Select the baseline scenario

dis_mod.scenario baseline

' Set simulation sample
smpl 1946 @last

' Solve the model for the current sample

dis_mod.solve

' Creates charts from simulated variables

' Creates the chart in Figure A9.1
smpl 1955 2000
graph figA9_1.line s_k_e y_k_0 s_k_0
figA9_1.options linepat
figA9_1.setelem(1) lcolor(blue) lwidth(1) lpat(1)
figA9_1.setelem(2) lcolor(red) lwidth(2) lpat(2)
figA9_1.setelem(3) lcolor(green) lwidth(2) lpat(3)
figA9_1.name(1) Expected real sales (exogenous)
figA9_1.name(2) Real output
figA9_1.name(3) Real sales
figA9_1.addtext(t) Figure A9.1: Evolution of real output and real sales following an increase in expected sales

show figA9_1

' Creates the chart in Figure A9.2
smpl 1955 2000
graph figA9_2.line s_k_e-s_k_0 -(in_k_e_0-in_k_0(-1))
figA9_2.options linepat
figA9_2.setelem(1) lcolor(red) lwidth(2) lpat(1)
figA9_2.setelem(2) lcolor(green) lwidth(2) lpat(2)
figA9_2.name(1) Overestimate of real sales
figA9_2.name(2) Desired reduction in physical inventories
figA9_2.addtext(t) Figure A9.2: Convergence of the overestimate of real sales\nwith the desired reduction in physical inventories\nfollowing an increase in expected sales

show figA9_2