' MODEL PCEX for Eviews version 4.1
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 4

' This program creates model PCEX, described in chapter 4, and simulates the model
' to produce results in figures 4.1 & 4.2,
' discussed in par. 4.4


' ****************************************************************************
' Copyright (c) 2006 Gennaro Zezza
' Permission is hereby granted, free of charge, to any person obtaining a 
' copy of this software and associated documentation files (the "Software"),
' to deal in the Software without restriction, including without limitation
' the rights to use, copy, modify, merge, publish, distribute, sublicense, 
' and/or sell copies of the Software, and to permit persons to whom the 
' Software is furnished to do so, subject to the following conditions:
' 
' The above copyright notice and this permission notice shall be included in 
' all copies or substantial portions of the Software.
' 
' THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR 
' IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, 
' FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE 
' AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER 
' LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING 
' FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS 
' IN THE SOFTWARE.
' ****************************************************************************

' Create a workfile, naming it PCEX, to hold annual data from 1945 to 2010

create pcex a 1945 2010

' Creates and documents series
series b_cb
b_cb.displayname Government bills held by Central Bank
series b_d
b_d.displayname Demand for government bills
series b_h
b_h.displayname Government bills held by households
series b_s
b_s.displayname Government bills supplied by government
series cons
cons.displayname Consumption goods
series g
g.displayname Government goods
series h_d
h_d.displayname Demand for cash
series h_h
h_h.displayname Cash money held by households
series h_s
h_s.displayname Cash money supplied by central bank
series r
r.displayname Interest rate on government bills
series r_bar
r_bar.displayname Interest rate as policy instrument
series ra
ra.displayname Random shock to expectations
series t
t.displayname Taxes
series v
v.displayname Households wealth
series v_e
v_e.displayname Expected households wealth
series y
y.displayname Income = GDP
series yd
yd.displayname Disposable income of households
series yd_e
yd_e.displayname Expected disposable income of households

' Generate parameters
series alpha1
alpha1.displayname Propensity to consume out of income
series alpha2
alpha2.displayname Propensity to consume out of wealth
series lambda0
lambda0.displayname Parameter in asset demand function
series lambda1
lambda1.displayname Parameter in asset demand function
series lambda2
lambda2.displayname Parameter in asset demand function
series theta
theta.displayname Tax rate

' Set sample size to all workfile range
smpl @all

' Assign values for
'   PARAMETERS
alpha1=0.6
alpha2=0.4
lambda0 = 0.635
lambda1 = 5
lambda2 = 0.01
theta=0.2
'   EXOGENOUS
g=20
smpl @all
r_bar = 0.025
r = r_bar
'   Starting values for stocks
b_cb = 116.36
b_h = 363.59
b_s = b_h+b_cb
h_h = 116.35
h_s = h_h
v = b_h + h_h
' Random shock
smpl @first 1959
ra = 0
smpl 1960 @last
ra = nrnd/10
smpl @all

' Create a model object, and name it pcex_mod

model pcex_mod

' Add equations to model PCEX

' Determination of output - eq. 4.1
pcex_mod.append y = cons + g

' Disposable income - eq. 4.2
pcex_mod.append yd = y - t + r(-1)*b_h(-1)

' Tax payments - eq. 4.3
pcex_mod.append t = theta*(y + r(-1)*b_h(-1))

' Wealth accumulation - eq. 4.4
pcex_mod.append v = v(-1) + (yd - cons)

' Consumption function - eq. 4.5e
pcex_mod.append cons = alpha1*yd_e + alpha2*v(-1)

' Demand for government bills - eq. 4.7e
pcex_mod.append b_d = v_e*(lambda0 + lambda1*r - lambda2*(yd_e/v_e))

' Demand for cash money - eq. 4.13
pcex_mod.append h_d = v_e - b_d

' Expected wealth - eq. 4.14
pcex_mod.append v_e = v(-1) + (yd_e - cons)

' Cash money held by households - eq. 4.6
pcex_mod.append h_h = v - b_h

' Government bills held by households - eq. 4.15
pcex_mod.append b_h = b_d

' Supply of government bills - eq. 4.8
pcex_mod.append b_s = b_s(-1) + (g + r(-1)*b_s(-1)) - (t + r(-1)*b_cb(-1))

' Supply of cash - eq. 4.9
pcex_mod.append h_s = h_s(-1) + b_cb - b_cb(-1)

' Government bills held by the central bank - eq. 4.10
pcex_mod.append b_cb = b_s - b_h

' Interest rate as policy instrument - eq. 4.11
pcex_mod.append r = r_bar

' Expected disposable income - eq. 4.16
pcex_mod.append yd_e = yd*(1 + ra)

' End of model

' Select the baseline scenario

pcex_mod.scenario baseline

' Drop first observation to get starting values for solving the model
smpl 1946 @last

' Solve the model for the current sample

pcex_mod.solve

' Creates charts from simulated variables

' Creates the chart in Figure 4.1
smpl 1977 1999
graph fig4_1.line h_d_0 h_h_0
fig4_1.options linepat
fig4_1.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig4_1.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig4_1.name(1) Money demand
fig4_1.name(2) Held money balances
fig4_1.addtext(t) Figure 4.1: Hd and Hh when the economy is subjected to random shocks

show fig4_1

' Creates the chart in Figure 4.2
smpl 1977 1999
graph fig4_2.line d(h_d_0) d(h_h_0)
fig4_2.options linepat
fig4_2.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig4_2.setelem(2) lcolor(green) lwidth(2) lpat(2)
fig4_2.name(1) Change in money demand
fig4_2.name(2) Change in money held
fig4_2.addtext(t) Figure 4.2: Changes in Hd and Hh when the economy is subjected to random shocks

show fig4_2

@smpl all