' MODEL PCEX2 for Eviews version 4.1
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 4

' This program creates model pcex2, described in chapter 4, and simulates the model
' to produce results in figures 4.9 & 4.10,
' discussed in par. 4.6.3


' ****************************************************************************
' Copyright (c) 2006 Gennaro Zezza
' Permission is hereby granted, free of charge, to any person obtaining a 
' copy of this software and associated documentation files (the "Software"),
' to deal in the Software without restriction, including without limitation
' the rights to use, copy, modify, merge, publish, distribute, sublicense, 
' and/or sell copies of the Software, and to permit persons to whom the 
' Software is furnished to do so, subject to the following conditions:
' 
' The above copyright notice and this permission notice shall be included in 
' all copies or substantial portions of the Software.
' 
' THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR 
' IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, 
' FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE 
' AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER 
' LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING 
' FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS 
' IN THE SOFTWARE.
' ****************************************************************************

' Create a workfile, naming it pcex2, to hold annual data from 1945 to 2010

create pcex2 a 1945 2010

' Creates and documents series
series b_cb
b_cb.displayname Government bills held by Central Bank
series b_h
b_h.displayname Government bills held by households
series b_s
b_s.displayname Government bills supplied by government
series cons
cons.displayname Consumption goods
series g
g.displayname Government goods
series h_h
h_h.displayname Cash money held by households
series h_s
h_s.displayname Cash money supplied by central bank
series r
r.displayname Interest rate on government bills
series r_bar
r_bar.displayname Interest rate as policy instrument
series t
t.displayname Taxes
series v
v.displayname Households wealth
series y
y.displayname Income = GDP
series yd
yd.displayname Disposable income of households

' Generate parameters
series alpha1
alpha1.displayname Propensity to consume out of income
series alpha2
alpha2.displayname Propensity to consume out of wealth
series alpha10
alpha10.displayname Propensity to consume out of income - exogenous
series iota
iota.displayname Impact of interest rate on the propensity to consume out of income
series lambda0
lambda0.displayname Parameter in asset demand function
series lambda1
lambda1.displayname Parameter in asset demand function
series lambda2
lambda2.displayname Parameter in asset demand function
series theta
theta.displayname Tax rate

' Set sample size to all workfile range
smpl @all

' Assign values for
'   PARAMETERS
alpha1=0.6
alpha2=0.4
alpha10 = 0.7
iota = 4
lambda0 = 0.635
lambda1 = 5
lambda2 = 0.01
theta=0.2
'   EXOGENOUS
g=20
r_bar = 0.025
r = r_bar
'   Starting values for stocks
b_cb = 21.576
b_h = 64.865
b_s = b_h+b_cb
h_h = 21.62
h_s = h_h
v = b_h + h_h
' Starting value for disposable income
yd = 90
' Shock to interest rate in 1960
smpl 1960 @last
r_bar = r_bar + 0.01
smpl @all

' Create a model object, and name it pcex2_mod

model pcex2_mod

' Add equations to model pcex2

' Determination of output - eq. 4.1
pcex2_mod.append y = cons + g

' Disposable income - eq. 4.2
pcex2_mod.append yd = y - t + r(-1)*b_h(-1)

' Tax payments - eq. 4.3
pcex2_mod.append t = theta*(y + r(-1)*b_h(-1))

' Wealth accumulation - eq. 4.4
pcex2_mod.append v = v(-1) + (yd - cons)

' Consumption function - eq. 4.5e
pcex2_mod.append cons = alpha1*yd_e + alpha2*v(-1)

' Demand for government bills - eq. 4.7e
pcex2_mod.append b_d = v_e*(lambda0 + lambda1*r - lambda2*(yd_e/v_e))

' Demand for cash money - eq. 4.13
pcex2_mod.append h_d = v_e - b_d

' Expected wealth - eq. 4.14
pcex2_mod.append v_e = v(-1) + (yd_e - cons)

' Cash money held by households - eq. 4.6
pcex2_mod.append h_h = v - b_h

' Government bills held by households - eq. 4.15
pcex2_mod.append b_h = b_d

' Supply of government bills - eq. 4.8
pcex2_mod.append b_s = b_s(-1) + (g + r(-1)*b_s(-1)) - (t + r(-1)*b_cb(-1))

' Supply of cash - eq. 4.9
pcex2_mod.append h_s = h_s(-1) + b_cb - b_cb(-1)

' Government bills held by the central bank - eq. 4.10
pcex2_mod.append b_cb = b_s - b_h

' Interest rate as policy instrument - eq. 4.11
pcex2_mod.append r = r_bar

' Expected disposable income - eq. 4.16
pcex2_mod.append yd_e = yd(-1)

' Propensity to consume out of income - eq. 4.31
pcex2_mod.append alpha1 = alpha10 - iota*r(-1)

' End of model

' Select the baseline scenario

pcex2_mod.scenario baseline

' Drop first observation to get starting values for solving the model
smpl 1946 @last

' Solve the model for the current sample

pcex2_mod.solve

' Creates the chart in Figure 4.9
smpl 1957 2001
graph fig4_9.line v_0 y_0 yd_0 cons_0
fig4_9.options linepat
fig4_9.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig4_9.setelem(2) lcolor(blue) lwidth(2) lpat(2)
fig4_9.setelem(3) lcolor(green) lwidth(2) lpat(3)
fig4_9.setelem(4) lcolor(blue) lwidth(2) lpat(4)
fig4_9.name(1) Household wealth
fig4_9.name(2) National income (GDP)
fig4_9.name(3) Disposable income
fig4_9.name(4) Consumption
fig4_9.addtext(t) Figure 4.9: Evolution of GDP, C, YD and V following an increase in the interest rate

show fig4_9

' Creates the chart in Figure 4.10
smpl 1957 2001
graph fig4_10.line g+r_0(-1)*b_h_0(-1) t_0
fig4_10.options linepat
fig4_10.setelem(1) lcolor(red) lwidth(2) lpat(1)
fig4_10.setelem(2) lcolor(blue) lwidth(2) lpat(2)
fig4_10.name(1) Govt. exp. plus net debt service
fig4_10.name(2) Tax revenues
fig4_10.addtext(t) Figure 4.10: Evolution of Govt. receipts and expenditures following an increase in r

show fig4_10