' MODEL SIM for Eviews version 4.*
' from Wynne Godley & Marc Lavoie
' MONETARY ECONOMICS
' Chapter 3

' This program creates model SIM, described in chapter 3, and simulates the model
' to produce results in the appendix

' ****************************************************************************
' Copyright (c) 2006 Gennaro Zezza
' Permission is hereby granted, free of charge, to any person obtaining a 
' copy of this software and associated documentation files (the "Software"),
' to deal in the Software without restriction, including without limitation
' the rights to use, copy, modify, merge, publish, distribute, sublicense, 
' and/or sell copies of the Software, and to permit persons to whom the 
' Software is furnished to do so, subject to the following conditions:
' 
' The above copyright notice and this permission notice shall be included in 
' all copies or substantial portions of the Software.
' 
' THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR 
' IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, 
' FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE 
' AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER 
' LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING 
' FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS 
' IN THE SOFTWARE.
' ****************************************************************************

' Create a workfile, naming it SIM, to hold annual data from 1945 to 2010

create sim a 1945 2010

' Creates and documents series
series c_d
c_d.displayname Consumption goods demand by households
series c_s
c_s.displayname Consumption goods supply
series g_d
g_d.displayname Government goods, demand
series g_s
g_s.displayname Government goods, supply
series h_h
h_h.displayname Cash money held by households
series h_s
h_s.displayname Cash money supplied by government
series n_d
n_d.displayname Demand for labour
series n_s
n_s.displayname Supply of labour
series t_d
t_d.displayname Taxes, "demand"
series t_s
t_s.displayname Taxes, "supply"
series w
w.displayname Wage rate
series y
y.displayname Income = GDP
series yd
yd.displayname Disposable income of households

' Generate parameters
series alpha1
alpha1.displayname Propensity to consume out of income
series alpha2
alpha2.displayname Propensity to consume out of wealth
series theta
theta.displayname Tax rate

' Set sample size to all workfile range
smpl @all

' Assign values for
'   PARAMETERS
alpha1=0.6
alpha1=0.7
alpha2=0.4
theta=0.2
'   EXOGENOUS
' Note: government expenditure increases in 1960
smpl @first 1959
g_d=20
smpl 1960 @last
g_d=25
smpl @all
w=1
'   ENDOGENOUS (in steady state)
g_s = g_d
y = g_s/theta
yd =g_s*(1-theta)/theta
c_d = yd
c_s = c_d
h_h = (1-alpha1)*yd/alpha2
h_s = h_h
n_d = y/w
n_s = n_d
t_d = theta*w*n_s
t_s = t_d

' Create a model object, and name it sim_mod

model sim_mod

' Add equations to model SIM

sim_mod.append c_s = c_d
sim_mod.append g_s = g_d
sim_mod.append t_s = t_d
sim_mod.append n_s = n_d
sim_mod.append yd = w*n_s - t_s
sim_mod.append t_d = theta*w*n_s
sim_mod.append c_d = alpha1*yd + alpha2*h_h(-1)
sim_mod.append h_s = h_s(-1) + g_d - t_d
sim_mod.append h_h = h_h(-1) + yd - c_d
sim_mod.append y = c_s + g_s
sim_mod.append n_d = y/w

' Select the baseline scenario

sim_mod.scenario baseline

' Solve the model for the current sample

sim_mod.solve


' Create variables for (simulated) changes in stocks
genr dh_s_0 = h_s_0 - h_s_0(-1)
genr dh_h_0 = h_h_0 - h_h_0(-1)

' Creates charts from simulated variables


' Creates the chart in Figure A3.1
smpl 1957 2001
graph figA3_1.line g_d-20 t_d_0-20
figA3_1.options linepat
figA3_1.setelem(1) lwidth(2) lpat(1)
figA3_1.setelem(2) lwidth(2) lpat(2)
figA3_1.name(1) Government expenditure G
figA3_1.name(2) Tax revenues Td
figA3_1.addtext(t) Figure A3.1: The mean lag theorem: speed at which the economy adjusts

show figA3_1

' Now we change the propensity to consume
smpl @all
alpha1 = 0.9

'   ENDOGENOUS (in steady state)
g_s = g_d
y = g_s/theta
yd =g_s*(1-theta)/theta
c_d = yd
c_s = c_d
h_h = (1-alpha1)*yd/alpha2
h_s = h_h
n_d = y/w
n_s = n_d
t_d = theta*w*n_s
t_s = t_d


' Select the alternative Scenario 1

sim_mod.scenario "Scenario 1"

' Solve the model for the current sample

sim_mod.solve


' Creates the chart in Figure A3.2
smpl 1957 2001
graph figA3_2.line g_d/theta y_0 y_1
figA3_2.options linepat
figA3_2.setelem(1) lwidth(2) lpat(1)
figA3_2.setelem(2) lwidth(2) lpat(2)
figA3_2.setelem(3) lwidth(2) lpat(3)
figA3_2.name(1) Steady state solution Y*
figA3_2.name(2) Income Y with low MPC (0.6)
figA3_2.name(3) Income Y with high MPC (0.9)
figA3_2.addtext(t) Figure A3.2: Adjustment of Y on different assumptions about the MPC

show figA3_2